; TRON 2

	ORG	60000
INIC	LD	A,5
	LD	(X1),A;X1=5
	LD	A,250
	LD	(X2),A;X2=250
	LD	A,88
	LD	(Y1),A;Y1=88
	LD	A,87
	LD	(Y2),A;Y2=87
	LD	A,1
	LD	(DX1),A;DX1=1
	XOR	A
	LD	(DY1),A;DY1=0
	LD	(DY2),A;DY2=0
	CPL
	LD	(DX2),A;DX2=-1
SCR	CALL	#0D6B;CLS
	EXX
	PUSH	HL
	EXX
	LD	C,255
	LD	B,0
	LD	E,1
	LD	D,1
	CALL	#24BA;DRAW255,0
	LD	C,0
	LD	B,175
	LD	E,1
	LD	D,1
	CALL	#24BA;DRAW0,175
	LD	C,255
	LD	B,0
	LD	E,255
	LD	D,1
	CALL	#24BA;DRAW-255,0
	LD	C,0
	LD	B,175
	LD	E,1
	LD	D,255
	CALL	#24BA;DRAW0,-175
	EXX
	POP	HL
	EXX
COORD1	LD	A,(X1)
	LD	HL,DX1
	ADD	A,(HL)
	LD	(X1),A;X1=X1+DX1
	LD	A,(Y1)
	LD	HL,DY1
	ADD	A,(HL)
	LD	(Y1),A;Y1=Y1+DY1
	LD	A,(X1)
	CALL	#2D28
	LD	A,(Y1)
	CALL	#2D28
	CALL	#22CB;POINT(X,Y)
	CALL	#2314;A=POINT(X,Y)
	AND	A
	JP	NZ,FIN1
DIB1	LD	A,(X1)
	CALL	#2D28
	LD	A,(Y1)
	CALL	#2D28
	CALL	#22DC;PLOT(X1,Y1)
COORD2	LD	A,(X2)
	LD	HL,DX2
	ADD	A,(HL)
	LD	(X2),A;X2=X2+DX2
	LD	A,(Y2)
	LD	HL,DY2
	ADD	A,(HL)
	LD	(Y2),A;Y2=Y2+DY2
	LD	A,(X2)
	CALL	#2D28
	LD	A,(Y2)
	CALL	#2D28
	CALL	#22CB;POINT(X,Y)
	CALL	#2314;A=POINT(X,Y)
	AND	A
	JP	NZ,FIN2
DIB2	LD	A,(X2)
	CALL	#2D28
	LD	A,(Y2)
	CALL	#2D28
	CALL	#22DC;PLOT(X2,Y2)
	LD	DE,3000
RETARD	DEC	DE
	LD	A,E
	OR	D
	JR	NZ,RETARD
KEY	CALL	#028E;KEY_SCAN
	LD	A,D
	CP	#FF
	JR	Z,KEY1
	LD	A,D
	CALL	SCAN
KEY1	LD	A,E
	CALL	SCAN
	JP	COORD1
SCAN	CP	#1C;"2"
	JR	Z,UP1
	CP	#1E;"S"
	JR	Z,DOWN1
	CP	#25;"Q"
	JR	Z,LEFT1
	CP	#15;"E"
	JR	Z,RIGHT1
	CP	#13;"8"
	JR	Z,UP2
	CP	#11;"K"
	JR	Z,DOWN2
	CP	#0A;"U"
	JR	Z,LEFT2
	CP	#1A;"O"
	JR	Z,RIGHT2
	RET
DOWN1	LD	A,255
	LD	(DY1),A;DY1=-1
	XOR	A
	LD	(DX1),A;DX1=0
	RET
UP1	LD	A,1
	LD	(DY1),A;DY1=1
	XOR	A
	LD	(DX1),A;DX1=0
	RET
LEFT1	LD	A,255
	LD	(DX1),A;DX1=-1
	XOR	A
	LD	(DY1),A;DY1=0
	RET
RIGHT1	LD	A,1
	LD	(DX1),A;DX1=1
	XOR	A
	LD	(DY1),A;DY1=0
	RET
DOWN2	LD	A,255
	LD	(DY2),A
	XOR	A
	LD	(DX2),A
	RET
UP2	LD	A,1
	LD	(DY2),A
	XOR	A
	LD	(DX2),A
	RET
LEFT2	LD	A,255
	LD	(DX2),A
	XOR	A
	LD	(DY2),A
	RET
RIGHT2	LD	A,1
	LD	(DX2),A
	XOR	A
	LD	(DY2),A
	RET
FIN1	LD	DE,STR1
	JR	FIN
FIN2	LD	DE,STR2
FIN	PUSH	DE
	LD	A,2
	CALL	#1601
	POP	DE
	LD	BC,14
	CALL	#203C;PRINT
	RET	;FINAL
;
;
X1	DEFB	5
Y1	DEFB	88
DX1	DEFB	1
DY1	DEFB	0
X2	DEFB	250
Y2	DEFB	88
DX2	DEFB	255
DY2	DEFB	0
STR1	DEFM	"GANA JUGADOR 2"
STR2	DEFM	"GANA JUGADOR 1"

	END      